Setup LLVM development on Windows

[ samkhn Home | Comments or bugs? Contact me ]

Setup LLVM development on Windows

Published: February 5, 2023

Recommendation 0: Read the docs mainly. LLVM docs are actually good. This will cover some areas in between what's documented and what works. I'll try to eventually merge this into the mainline LLVM docs.

Recommendation 1: Create a shell just for LLVM. First create a batch script that sets the PATH to LLVM dependencies (called something like llvm-setup.bat). Create a shortcut for cmd.exe. Have the shortcut run %comspec% /k "C:\path\to\llvm-setup.bat".

Here is what I ended up using


      
	 
	@ECHO OFF
	 
	:: LLVM Project Shell
	:: Sets path so that LLVM can build
	SET PROJDIR=C:\path\to\llvm-project
	 
	SET "PATH=C:\Program Files (x86)\GnuWin32\bin;%PATH%"
	SET "PATH=C:\Program Files\SWIG\swigwin-4.1.1;%PATH%"
	SET "PATH=C:\Program Files\Python311;%PATH%"
	IF NOT DEFINED DevEnvDir (
	  CALL "C:\Program Files\Microsoft Visual Studio\2022\Community\VC\Auxiliary\Build\vcvars64.bat" >nul
	)
	SET "PATH=C:\Program Files\CMake\bin;%PATH%"
	 
	PUSHD %PROJDIR%

Some nice features of the batch script

ECHO OFF keeps cmd prompt clean.
User and System PATH remains clean.
We add a newer version of CMake so we can have some of the latest features. We prepend CMake to the path so that it takes priority over the Visual Studio CMake.
PUSHD pushes the LLVM directory onto a stack. If you invoke POPD, you'll be placed back to wherever you called PUSHD from.

Recommendation 2: PTAL at path\to\llvm-project\llvm\utils. Emacs, vim and editor configs are stored here.

Recommendation 3: Create your own build script that calls CMake (unless you want to manually type it in).

Here is what I ended up using (assuming you are using the LLVM shell, which gives access to 64 bit MSVC cl.exe)


      
	 
	@ECHO OFF
	 
	:: LLVM build
	SET DBGDIR=%PROJECTDIR%\build-debug
	 
	:: Tells CMake to Use CL, not Clang, to build binaries
	SET CC=cl.exe
	SET CXX=cl.exe
	 
	SET "NINJAx86=-GNinja -DLLVM_TARGETS_TO_BUILD=X86"
	SET "LLDBDBGOPTS=-DLLDB_TEST_DEBUG_TEST_CRASHES=1 -DLLDB_EXPORT_ALL_SYMBOLS=1"
	SET LLVMDIR=C:\LLVM\llvm
	 
	IF NOT EXIST %DBGDIR% MKDIR %DBGDIR%
	cmake %NINJAx86% -B %DBGDIR% -DCMAKE_BUILD_TYPE=Debug -DLLVM_ENABLE_PROJECTS="clang;lld;lldb" %LLDBDBGOPTS% -S %LLVMDIR%

Some suggestions and gotchas to look out for

Use -S C:\path\to\llvm-proj\llvm, regardless of what you intend to build (passed to -DLLVM_ENABLE_PROJECTS). I missed this and thought I needed to pass C:\path\to\llvm-proj\clang to build clang.
Use MSVC toolchain (not the released LLVM binaries found on their page). When you use clang, the cmake scripts look for LLVM headers. These don't exist IIUC, since the Windows version of clang uses MSVC libraries under the hood.
Use 64 bit link.exe. When I accidently used the 32 bit linker, I smelled the inside of the laptop for the first time after CPU utilization hit 100%, memory usage hit 100% and the fans went into 100% their intended frequencey. So pass x64 to vcvarsall.bat or open the 64 bit tooling VsDevCmd EVEN IF you are generating Ninja build files. Otherwise, it might use the default 32 bit linker.
Use -DLLVM_TARGETS_TO_BUILD=X86, replacing x86 with your desired architecture. Otherwise, you will build for all hardware architectures.
Use release with asserts: -DCMAKE_BUILD_TYPE=Release -DLLVM_ENABLE_ASSERTIONS=ON
Probably the most impactful advice: reduce the number of parallel builds. On my machine (12 core Intel i5), my processor often overheated and froze to preserve itself when running all cores at once. Once I ran with 6 cores, build time increased but they completed.